clear all
set more on
use "C:\Users\Toshiba\Desktop\Ronald\Universidad\Ramos (Equipo Docente)\Aplicaciones de probabilidades y estadísticas para la gestión 2017-1\Auxiliares\Auxiliar 02\Auxiliar 02 Pauta\Casen 2015.dta", clear

** Instalar comando outreg2 ****************************************************
ssc install outreg2 //outreg 2 sirve para exportar tablas de regresiones a Excel

********************************************************************************
** TRATAMIENTO DE LA BASE DE DATOS *********************************************
********************************************************************************

keep expr folio edad e13b e15a qaut pco1 ytoth //Dejamos sólo vars que interesan

** Calcular gasto en educación de la persona ***********************************
replace e13b=0 if e13b==.
replace e15a=0 if e15a==.
gen gastoeduc=e13b+e15a

** Edad del jefe(a) de hogar ***************************************************
gen ejh=edad if pco1==1
gen ejh2=ejh^2

** Agrupar por hogares *********************************************************
collapse (sum) ejh ejh2 gastoeduc (mean) ytoth qaut expr, by(folio)


********************************************************************************
** REGRESIONES *****************************************************************
********************************************************************************

** 1. Regresión del gasto en educ. en función de ejh y ejh2 ********************
reg gastoeduc ejh ejh2 [pw=expr] if ejh<=65 & ejh>=25
outreg2 using "C:\Users\Toshiba\Desktop\Ronald\Universidad\Ramos (Equipo Docente)\Aplicaciones de probabilidades y estadísticas para la gestión 2017-1\Auxiliares\Auxiliar 02\Auxiliar 02 Pauta\reg1.xls", excel replace

** 2. Regresión del gasto en educ. en función de ejh, ejh2 e ytoth *************
reg gastoeduc ejh ejh2 ytoth [pw=expr] if ejh<=65 & ejh>=25
outreg2 using "C:\Users\Toshiba\Desktop\Ronald\Universidad\Ramos (Equipo Docente)\Aplicaciones de probabilidades y estadísticas para la gestión 2017-1\Auxiliares\Auxiliar 02\Auxiliar 02 Pauta\reg2.xls", excel replace

** 3. Regresión del gasto en educ. en función de ejh, ejh2 e ytoth por quintil**
reg gastoeduc i.qaut#c.ytoth i.qaut#c.ejh i.qaut#c.ejh2 [pw=expr] if ejh<=65 & ejh>=25
outreg2 using "C:\Users\Toshiba\Desktop\Ronald\Universidad\Ramos (Equipo Docente)\Aplicaciones de probabilidades y estadísticas para la gestión 2017-1\Auxiliares\Auxiliar 02\Auxiliar 02 Pauta\reg3.xls", excel replace


********************************************************************************
** TEOREMA DE FRISCH - WAUGH ***************************************************
********************************************************************************

reg gastoeduc ejh ejh2 [pw=expr] if ejh<=65 & ejh>=25
predict u_gastoeduc_ejh_ejh2, resid

reg ytoth ejh ejh2 [pw=expr] if ejh<=65 & ejh>=25
predict u_ytoth_ejh_ejh2, resid 

reg u_gastoeduc_ejh_ejh2 u_ytoth_ejh_ejh2 [pw=expr] if ejh<=65 & ejh>=25

********************************************************************************
** MODELO LOG - LIN ************************************************************
********************************************************************************

gen log_gastoeduc = ln(gastoeduc)

** 4. Regresión del log. del gasto en educ. en función de ejh, ejh2 e ytoth ****
reg log_gastoeduc ejh ejh2 ytoth [pw=expr] if ejh<=65 & ejh>=25
outreg2 using "C:\Users\Toshiba\Desktop\Ronald\Universidad\Ramos (Equipo Docente)\Aplicaciones de probabilidades y estadísticas para la gestión 2017-1\Auxiliares\Auxiliar 02\Auxiliar 02 Pauta\reg4.xls", excel replace