/*
En este ejemplo se muestra como la aplicación de una 
escala con valores negativos permite reflejar una figura en diferentes direcciones.

Si se fijan en el código, notarán que al igual como sucedía en 
el caso de rotate(), se hace necesario aplicar un translate() para el objeto
pueda estar nuevamente dentro del área visible de la pantalla.

El valor de este translate, es decir, hacia donde se desplaza el objeto en términos de x,y
lo deben determinar ustedes para su propio dibujo (esto es el encargo que deben traer resuelto 
para la próxima sesión recuperativa). Esto se puede deducir utilizando 
como referencia las guías magenta presentes en este ejemplo, las cuales representan los ejes 
mediante los cuales se hace la reflexión.
*/

void setup(){
  size(400,400);
}

void draw(){
  //grilla
  for(int y=0; y<height; y+=20){
    for(int x=0; x<width; x+=20){
      pushStyle();
      noFill();
      rect(x,y,20,20);
      popStyle();
    }
  }
  
  //caso uno (figura roja)
  dibujar(1);
  //caso dos (figura verde)
  dibujar(2);
  //caso tres (figura azul)
  dibujar(3);
  //caso cuatro (figura blanca (original))
  dibujar(4);
  
  //estas son las guías magenta que marcan el centro del lienzo
  pushStyle();
  stroke(255,0,255);
  line(width/2,0,width/2,height);
  line(0,height/2,width,height/2);
  popStyle();
}


void dibujar(float mode){
  int m = int(mode);
  
  pushMatrix();
  //caso uno (figura roja)
  if(m == 1){
    translate(width/2,height/2);
    scale(-1,-1);
    fill(255,0,0);
  //caso dos (figura verde)
  }else if(m == 2){
    translate(width/2,height/2);
    scale(1,-1);
    fill(0,255,0);
  //caso tres (figura azul)
  }else if(m == 3){
    translate(width/2,height/2);
    scale(-1,1);
    fill(0,0,255);
  }else{
    translate(width/2,height/2);
    scale(1,1);
    fill(255);
  }
 
    beginShape();
      vertex(0, 0);
      vertex(20, 0);
      vertex(20, 20);
      vertex(40, 20);
      vertex(40, 40);
      vertex(0, 40);
    endShape(CLOSE);
  popMatrix();
}